循环

Groovy支持常见的while {…}循环，就像Java一样。

def x = 0
def y = 5
 
while ( y-- > 0 ) {
    x++
}
 
assert x == 5

在Groovy中，for循环更加简单，并且它可以总在数组、集合（collection）和映射（map）等等上。

注意：如果你想要的话，你也可以使用Java/C中标准的for循环。

// for (int i = 0; i < 5; ++i) // 在beta-10之前都没有实现。
 
// 迭代一个范围
def x = 0
for ( i in 0..9 ) {
    x += i
}
assert x == 45
 
// 迭代一个列表
x = 0
for ( i in [0, 1, 2, 3, 4] ) {
    x += i
}
assert x == 10
 
// 迭代一个数组
array = (0..4).toArray()
x = 0
for ( i in array ) {
    x += i
}
assert x == 10
 
// 迭代一个映射
def map = ['abc':1, 'def':2, 'xyz':3]
x = 0
for ( e in map ) {
    x += e.value
}
assert x == 6
 
// 迭代一个映射中的值
x = 0
for ( v in map.values() ) {
    x += v
}
assert x == 6
 
// 迭代一个字符串中的字符
def text = "abc"
def list = []
for (c in text) {
    list.add(c)
}
assert list == ["a", "b", "c"]

另外，你可以使用闭包来代替大多数的for循环，通过使用each()和eachWithIndex()来实现：

def stringList = [ "java", "perl", "python", "ruby", "c#", "cobol",
                   "groovy", "jython", "smalltalk", "prolog", "m", "yacc" ];
 
def stringMap = [ "Su" : "Sunday", "Mo" : "Monday", "Tu" : "Tuesday",
                  "We" : "Wednesday", "Th" : "Thursday", "Fr" : "Friday",
                  "Sa" : "Saturday" ];
 
stringList.each() { print " ${it}" }; println "";
// java perl python ruby c# cobol groovy jython smalltalk prolog m yacc
 
stringMap.each() { key, value -> println "${key} == ${value}" };
// Su == Sunday
// We == Wednesday
// Mo == Monday
// Sa == Saturday
// Th == Thursday
// Tu == Tuesday
// Fr == Friday
 
stringList.eachWithIndex() { obj, i -> println " ${i}: ${obj}" };
// 0: java
// 1: perl
// 2: python
// 3: ruby
// 4: c#
// 5: cobol
// 6: groovy
// 7: jython
// 8: smalltalk
// 9: prolog
// 10: m
// 11: yacc
 
stringMap.eachWithIndex() { obj, i -> println " ${i}: ${obj}" };
// 0: Su=Sunday
// 1: We=Wednesday
// 2: Mo=Monday
// 3: Sa=Saturday
// 4: Th=Thursday
// 5: Tu=Tuesday
// 6: Fr=Friday